github::ActivityMonitor method discover (protected)

 <instance of github::ActivityMonitor[i]> discover jobsVar heads

Defined in packages/xowiki/tcl/github-activity-monitor-procs.tcl

Parameters:
jobsVar (required)
heads (required)

Testcases:
No testcase defined.
Source code:
upvar 1 $jobsVar jobs
set cursor [:get_state repository_discovery {}]
set now [clock seconds]
if {$cursor eq ""} {
    if {$now - [:get_state last_repository_reconcile 0] < ${:reconcile_interval}} {
        return
    }
    set cursor [dict create repo_page 1 repos {} branch_page 1]
}
set allowance [expr {min(${:discovery_requests_per_run}, max(1, ${:max_requests_per_run} / 4))}]
set stop [expr {${:requests_left} - $allowance}]
while {${:requests_left} > $stop} {
    set repos [dict get $cursor repos]
    if {[llength $repos] == 0} {
        if {[dict exists $cursor repos_done]} {
            :set_state repository_discovery {}
            :set_state last_repository_reconcile $now
            return
        }
        set page [dict get $cursor repo_page]
        set repos [::util::json2dict [:get "/orgs/${:organization}/repos" [list page $page]]]
        dict incr cursor repo_page
        dict set cursor repos $repos
        if {[llength $repos] < 100} {dict set cursor repos_done 1}
        :set_state repository_discovery $cursor
        continue
    }
    set repo [dict get [lindex $repos 0] full_name]
    set page [dict get $cursor branch_page]
    set branches [::util::json2dict [:get "/repos/$repo/branches" [list page $page]]]
    foreach item $branches {
        set branch [dict get $item name]
        set sha [dict get $item commit sha]
        set key [list $repo $branch]
        if {![dict exists $heads $key] || [dict get $heads $key] ne $sha} {
            :queue_backfill jobs $repo $branch $sha
        }
    }
    if {[llength $branches] < 100} {
        dict set cursor repos [lrange $repos 1 end]
        dict set cursor branch_page 1
    } else {
        dict incr cursor branch_page
    }
    :set_state pending_backfills $jobs
    :set_state repository_discovery $cursor
}
XQL Not present:
Generic, PostgreSQL, Oracle
[ hide source ] | [ make this the default ]
Show another procedure: