github::ActivityMonitor method get (public)

 <instance of github::ActivityMonitor[i]> get path [ query_args ]

Defined in packages/xowiki/tcl/github-activity-monitor-procs.tcl

Issue an API call on GitHub for the configured organization.

Parameters:
path (required)
query_args (optional)

Testcases:
No testcase defined.
Source code:
:check_rate_limit
:charge_request
set url "${:api_base}${path}"

# default query arg
dict set query per_page 100
foreach {k v} $query_args {
    dict set query $k $v
}
set urlDict [ns_parseurl $url]
dict set urlDict query [join [lmap {k v} $query {string cat [ns_urlencode -part query $k]=[ns_urlencode -part query $v]}] &]

set headers [ns_set create headers  Authorization "Bearer ${:api_token}"  Accept        "application/vnd.github+json"  User-Agent    "openacs-activity-dashboard/1.0"  ]

# Do not log the Authorization header.
ns_log notice "GitHub GET [ns_joinurl $urlDict]"
set timeout 15
if {[info exists :deadline]} {
    set timeout [expr {min(15, max(1, ${:deadline} - [clock seconds]))}]
}
set result [ns_http run -timeout $timeout -method GET -headers $headers [ns_joinurl $urlDict]]
set status [dict get $result status]
set body   [dict get $result body]
set rate_headers {}
if {[dict exists $result headers]} {
    set response_headers [dict get $result headers]
    foreach name {x-ratelimit-remaining x-ratelimit-reset retry-after} {
        dict set rate_headers $name [ns_set iget $response_headers $name]
    }
}
:record_rate_limit $status $rate_headers $body

if {$status < 200 || $status >= 300} {
    ns_log Error "GitHub GET $url failed: status $status, body: $body"
    return -code error -errorcode [list GITHUB HTTP $status] "GitHub API error $status"
}
return $body
XQL Not present:
Generic, PostgreSQL, Oracle
[ hide source ] | [ make this the default ]
Show another procedure: