Forum OpenACS Development: Saving base64 url to a image file

Hi there, I'm trying to save the following base64 URL https://iurix.com/img.base64 to an image file, however, the final PNG image displays an empty black square.

Downloading the PNG file and trying to open in an image viewer tells that the file has been corrupted.

I've tried to convert it with and without the first part "data:image/png;base64".

Plus, I've used both methods nsbase64urldecode and nsbase64decode

None of them worked successfully.

How must I convert from base64 to PNG ?

Here it is the chunk of code to convert from base64url to binary PNG

        set image_base64 [split $arr(image) ","]
        set mime_type [lindex $image_base64 0]
        switch $mime_type {
            case "data:image/png;base64" {
                set mime_type "image/png"
            }
            case "data:image/jpg;base64" "data:image/jpeg;base64" {
                set mime_type "image/jpg"
            }
            case "data:image/gif;base64" {
                set mime_type "image/gif"
            }
            default {
                set mime_type ""
            }
        }
        set tmp_file [ns_mktemp]
        set fp [open $tmp_file w]
        puts $fp [ns_base64urldecode [lindex $image_base64 1]]
        close $fp

Hi Iuru,

There are a few quirks in your code sample (ns_mktemp takes a template argument; the switch statement shouldn't include the "case" part) -- but leaving that aside I think you need to switch your file socket to be binary using fconfigure.

This is probably a good starting point to solve your problem (with $raw being the data from the url):

 lassign [split $raw ","] header data
 
 # NOTE: Much better data validation is required here

 switch -exact $header {
   "data:image/png;base64" {
      set mime_type "image/png"
   }
   default {
     error "unsupported type"
   } 
 }

 set filename [ns_mktemp /tmp/base64-image-XXXXXX]

 set fd [open $filename w]
 fconfigure $fd -translation binary 
 package require base64
 puts $fd [base64::decode $data]
 close $fd

 ns_returnfile 200 $mime_type $filename

One can also use the built-in bas64decode, which is much faster:

  lappend _ [time {base64::decode $data} 1000]
  lappend _ [time {ns_base64decode -binary $data} 1000]

returns

{1757.215183 microseconds per iteration} {343.221319 microseconds per iteration}

In case, the content has just to be displayed, the file handing can be omitted.

 set r [ns_http run https://iurix.com/img.base64]
 lassign [split [dict get $r body] ,] header data

 switch -exact $header {
     "data:image/png;base64" { set mime_type "image/png" }
     default { error "unsupported type"} 
 }

 ns_return -binary 200 $mime_type [ns_base64decode -binary $data]

-gn

[1] https://bitbucket.org/naviserver/naviserver/src/081829e43606b0e50baf3f258649ce4311358e10/NEWS#lines-220