Forum OpenACS Q&A: datetime to "Nice Dates"

Is there a procedure that will take the postgresql datetime that appears as "2000-07-18 15:04:56-04" and convert it to: (based on sysdate)

• Today at 3:04PM
• Yesterday at 8:00PM
• Tuesday, July 4th
• Saturday, Dec 25, 1999

(Display changes based on today. Back on July 4th we might not care what the time is....

Or is there something close that I can modify to accomplish this?
TIA - Bob OConnor

Given the examples you gave, I wrote the following Tcl procedure that do what you want:

proc pretty_pg_date {pg_date} {
    set pgtime [clock scan $pg_date]
    set now    [ns_time]
    set diff   [expr $now - $pgtime]
 
    if {$diff < 0} {
        set diff [expr abs($diff)]
        set neighbor Tomorrow
        set neighbor_day -86400
    } else {
        set neighbor Yesterday
        set neighbor_day 86400
    }
 
    # 31536000 seconds in a 365-day year
    if {$diff > 31536000} {
        return [ns_fmttime $pgtime "%A, %b %e, %Y"]
    }
 
    set pg_day_of_year [ns_fmttime $pgtime %j]
    set now_day_of_year [ns_fmttime $now %j]
 
    if {[string compare $pg_day_of_year $now_day_of_year] == 0} {
        return "Today at [string trimleft [ns_fmttime $pgtime %I:%M%p] 0]"
    }
 
    set neighbor_day_of_year [ns_fmttime [expr $pgtime + $neighbor_day] %j]
 
    if {[string compare $now_day_of_year $neighbor_day_of_year] == 0} {
        return "$neighbor at [string trimleft [ns_fmttime $pgtime %I:%M%p] 0]"
    }
 
    switch -- [ns_fmttime $pgtime %d] {
        01  -
        21  -
        31  { set suffix st }
        02  -
        22  { set suffix nd }
        03  { set suffix rd }
        default { set suffix th }
    }
 
    return [ns_fmttime $pgtime "%A, %b %e"]$suffix
 
}

This will only work on AOLserver 3.0 (since AOLserver 2.3 is Tcl 7.4-based, and the clock scan command wasn't added until Tcl 7.6). It also only works on dates between the start of the epoch, up through integer overflow (ie January 1, 1970 — sometime in August(?) of 2038).

Did you make sure your AOLServer's tcl is directed to the version 8 binary?  Check your bin directory; by default it will look like this:

lrwxrwxrwx    1 nsadmin  nsadmin        7 Jul  5 16:36 nsd -> ./nsd76*

-rwxr-xr-x    1 nsadmin  nsadmin  1703824 Jul  5 16:30 nsd76*

-rwxr-xr-x    1 nsadmin  nsadmin  2649930 Jul  5 16:30 nsd8x*

You want nsd to be a link to nsd8x instead of nsd76; cd to the bin dir and run "ln -sf nsd8x nsd".

Strange... though the email alert version of my posting has the proper regsub substitution, the bboard HTML version ends up just replacing the YYYY-MM-DD with " / / " instead of "MM/DD/YYYY". Let me repost the regsub in a plaintext and hope it works:

regsub {^([12][0-9][0-9][0-9])-([01][0-9])-([0-3][0-9])} $pg_date
{//
} pg_date

Well, FAR OUT! And thanks, It works and it's optional using the /bboard/admin-home.tcl page by specifying kooldate instead of date.

It turns out that I'm using nsd8x and didn't need the tcl7.6 fix but I discovered that I had forgot the $ in the proc

bboard_one_line_suffix

and the line:

set kooldate [pretty_pg_date $posting_time]

-Bob